Antwoord bij oefening 2.4

a. Construeer opnieuw de twee deelschalen voor de houding van de proefpersoon ten opzichte van de endorser (Clinton of Clooney). Gebruik hiervoor de variabelen aantrekkelijk tot en met geloofwaardig.
Wat is de correlatie tussen de ruwe scores op de twee deelschalen en de correlatie tussen de gestandaardiseerde scores (z-scores)? Wat is het verschil?

De correlatie tussen de twee ruwe schaalvariabelen is 0,42, net als de correlatie tussen de twee gestandaardiseerde schaalvariabelen. Ook de correlatie tussen een ongestandaardiseerde en een gestandaardiseerde schaalvariabele (mits het om verschillende deelschalen gaat) heeft exact deze waarde. Er is geen verschil.
Voor correlaties maakt het dus niet uit of de variabelen ruw of gestandaardiseerd zijn. Dit komt omdat je bij de berekening van de correlatie ook standaardiseert: je kijkt naar afwijkingen ten opzichte van het gemiddelde en je deelt door de standaarddeviaties.

Correlations
		Deelschaal1: betrouwbaarheid	Deelschaal2: aantrekkelijkheid	Zscore: Deelschaal1: betrouwbaarheid	Zscore: Deelschaal2: aantrekkelijkheid
Deelschaal1: betrouwbaarheid	Pearson Correlation	1	,417**	1,000**	,417**
	Sig. (2-tailed)		,000	,000	,000
	N	95	95	95	95
Deelschaal2: aantrekkelijkheid	Pearson Correlation	,417**	1	,417**	1,000**
	Sig. (2-tailed)	,000		,000	,000
	N	95	95	95	95
Zscore: Deelschaal1: betrouwbaarheid	Pearson Correlation	1,000**	,417**	1	,417**
	Sig. (2-tailed)	,000	,000		,000
	N	95	95	95	95
Zscore: Deelschaal2: aantrekkelijkheid	Pearson Correlation	,417**	1,000**	,417**	1
	Sig. (2-tailed)	,000	,000	,000
	N	95	95	95	95
**. Correlation is significant at the 0.01 level (2-tailed).

b. Ga na of je de houding ten opzicht van Darfur kunt voorspellen op grond van de twee deelschalen en het geslacht van de proefpersoon (variabele geslacht). Voer de analyse tweemaal uit: eenmaal met alleen ruwe scores en eenmaal met alle vier de variabelen gestandaardiseerd. Interpreteer de resultaten volgens de richtlijnen van het vak IS. Wat valt je op aan de resultaten?

Controleer eerst de variabelen geslacht en houding.
Bekijk vervolgens de spreidingsdiagrammen van de afhankelijke variabele houding met elk van de onafhankelijke numerieke variabelen (schaal1 en schaal2). In het spreidingsdiagram met deelschaal1 blijkt er een proefpersoon te zijn die duidelijk buiten de puntenwolk scoort (een bivariate uitbijter). Het is verstandig om deze proefpersoon (nummer 55) te verwijderen voordat je de regressieanalyses uitvoert. De spreidingsdiagrammen laten geen duidelijk krom verband zien, dus wat dit betreft kunnen we een lineaire regressieanalyse toepassen.
Je kunt deze proefpersoon identificeren door het spreidingsdiagrm in de Chart Editor te openen (dubbelklik op de grafiek) en daarin op de knop te klikken. Wanneer je nu met de muis op een punt in het spreidingsdiagram klikt, verschijnt het volgnummer van de proefpersoon in beeld.

De resultaten laten zien dat we de houding voor ongeveer een kwart (R² = 0,27) kunnen voorspellen op grond van een lineair regressiemodel met geslacht en de score op de twee deelschalen als voorspellers. Vrouwen blijken gemiddeld een 0,10 positievere houding te hebben ten opzichte van Darfur (b = 0,10). Wanneer de endorser betrouwbaarder wordt gevonden, is de houding positiever, dit is een matig tot sterk effect (schaal1: b* of Beta = 0,55). Wanneer de endorser aantrekkelijker gevonden wordt, is de houding juist minder positief, al gaat het hier om een zwak effect (schaal1: b* of Beta = -0,11). Coefficients^a

Model		Unstandardized Coefficients		Standardized Coefficients	t	Sig.
		B	Std. Error	Beta
1	(Constant)	3,054	,495		6,168	,000
	geslacht	,101	,186	,050	,541	,590
	schaal1	,554	,099	,552	5,572	,000
	schaal2	-,097	,087	-,113	-1,117	,267
a. Dependent Variable: houding

Coefficientsa
Model		Unstandardized Coefficients		Standardized Coefficients	t	Sig.
		B	Std. Error	Beta
1	(Constant)	-,001	,089		-,008	,994
	Zgeslacht	,050	,093	,050	,541	,590
	Zschaal1	,549	,098	,552	5,572	,000
	Zschaal2	-,113	,101	-,113	-1,117	,267
a. Dependent Variable: Zhouding

Wat opvalt uit een vergelijking tussen de resultaten met de ruwe variabelen en de resultaten met de gestandaardiseerde variabelen:

• De determinatiecoëfficiënt (R²) veranderen niet wanneer alle variabelen gestandaardiseerd worden.
  Eigenlijk om dezelfde reden waarom de correlatie ook niet verandert wanneer er gestandaardiseerd wordt, zie vraag a.
• De intercept (constante) wordt (vrijwel) 0 in de resultaten met gestandaardiseerde resultaten.
  Standaardisering zorgt ervoor dat de gemiddelde score op een variabele 0 wordt. Een gemiddelde score op alle onafhankelijke variabelen voorspelt de gemiddelde score op de afhankelijke variabele, dus de intercept oftewel de voorspelde waarde van de afhankelijke variabele als de onafhankelijke variabelen allemaal 0 zijn, is hier dus 0.
• De ongestandaardiseerde regressiecoëfficiënten (b) zijn (vrijwel) gelijk aan de gestandaardiseerde versies (b* of Beta) wanneer alle variabelen vooraf gestandaardiseerd zijn.
  Verbaast dit je? Het maakt niet uit of je de variabelen vooraf of tijdens de regressieanalyse standaardiseert.

Syntax

*a - constructie van schalen. *Beschrijven/controleren van items.
FREQUENCIES VARIABLES=aantrekkelijk stijlvol knap elegant sexy aardig eerlijk integer oprecht
   betrouwbaar vertrouwen geloofwaardig
  /ORDER=ANALYSIS.
*Waarde '17' als missing definieren.
* Define Variable Properties.
*integer.
MISSING VALUES integer(17).
EXECUTE.
*Factoranalyse.
FACTOR
  /VARIABLES aantrekkelijk stijlvol knap elegant sexy aardig eerlijk integer oprecht betrouwbaar
   vertrouwen geloofwaardig
  /MISSING LISTWISE
  /ANALYSIS aantrekkelijk stijlvol knap elegant sexy aardig eerlijk integer oprecht betrouwbaar
   vertrouwen geloofwaardig
  /PRINT INITIAL EXTRACTION ROTATION
  /PLOT EIGEN
  /CRITERIA MINEIGEN(1) ITERATE(25)
  /EXTRACTION PC
  /CRITERIA ITERATE(25)
  /ROTATION VARIMAX
  /METHOD=CORRELATION.
*Betrouwbaarheid deelschaal 1.
RELIABILITY
  /VARIABLES=aardig eerlijk integer oprecht betrouwbaar vertrouwen geloofwaardig
  /SCALE('ALL VARIABLES') ALL
  /MODEL=ALPHA
  /SUMMARY=TOTAL.
*Betrouwbaarheid deelschaal 2.
RELIABILITY
  /VARIABLES=aantrekkelijk stijlvol knap elegant sexy aardig
  /SCALE('ALL VARIABLES') ALL
  /MODEL=ALPHA
  /SUMMARY=TOTAL.
COMPUTE schaal1=Mean(aardig,eerlijk,integer,oprecht,betrouwbaar,vertrouwen,geloofwaardig).
EXECUTE.
*Berekenen van de schaalvariabelen.
COMPUTE schaal2=Mean(aantrekkelijk,stijlvol,knap,elegant,sexy,aardig).
EXECUTE.
* Define Variable Properties.
*schaal1.
VARIABLE LABELS schaal1 'Deelschaal1: betrouwbaarheid'.
*schaal2.
VARIABLE LABELS schaal2 'Deelschaal2: aantrekkelijkheid'.
EXECUTE.
*z-scores voor beide deelschalen berekenen.
DESCRIPTIVES VARIABLES=schaal1 schaal2
  /SAVE
  /STATISTICS=MEAN STDDEV MIN MAX.
*Correlaties tussen de ruwe of gestandaardiseerde scores.
CORRELATIONS
  /VARIABLES=schaal1 schaal2 Zschaal1 Zschaal2
  /PRINT=TWOTAIL NOSIG
  /MISSING=PAIRWISE.

*b - regressieanalyse met on/gestandaardiseerde variabelen.
*Controle van de variabele houding.
FREQUENCIES VARIABLES=geslacht houding
  /ORDER=ANALYSIS.
*Controle van spreidingsdiagrammen (het is niet nodig om de gestandaardiseerde variabelen ook te controleren).
GRAPH
  /SCATTERPLOT(BIVAR)=schaal1 WITH houding
  /MISSING=LISTWISE.
GRAPH
  /SCATTERPLOT(BIVAR)=schaal2 WITH houding
  /MISSING=LISTWISE.
*Weglaten bivariate uitbijter proefpersoon 55 (NB ~= is het teken voor "is ongelijk aan").
USE ALL.
COMPUTE filter_$=(proefpersoon ~= 55).
VARIABLE LABEL filter_$ 'proefpersoon ~= 55 (FILTER)'.
VALUE LABELS filter_$ 0 'Not Selected' 1 'Selected'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
EXECUTE.
*Regressie met ongestandaardiseerde variabelen.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT houding
  /METHOD=ENTER geslacht schaal1 schaal2.
*Standaardiseren van geslacht en houding.
DESCRIPTIVES VARIABLES=geslacht houding schaal1 schaal2
  /SAVE
  /STATISTICS=MEAN STDDEV MIN MAX.
*Regressie met gestandaardiseerde variabelen.
REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN
  /DEPENDENT Zhouding
  /METHOD=ENTER Zgeslacht Zschaal1 Zschaal2.